- Un budget de trésorerie ne prévoit pas des bénéfices mais des mouvements de banque : une vente de mars peut n’être encaissée qu’en mai, d’où l’importance des décalages.
- Les délais d’encaissement et de paiement sont des paramètres (pourcentages par mois) : une seule formule recopiée donne tous les mois.
- La TVA est un flux à part entière : collectée sur les ventes, récupérable sur les achats payés, reversée le mois suivant.
- Un scénario de retard des clients, avec les mêmes formules et d’autres paramètres, montre à quel mois la trésorerie passe sous le seuil d’alerte.
Une entreprise peut faire du bénéfice et tomber à découvert. La raison tient en un mot : décalage. Le client commande en mars, paie en mai ; le fournisseur est réglé en avril ; la TVA part le mois suivant. Le budget de trésorerie met ces décalages en tableau, mois par mois, pour dire à quelle date l’argent manquera, et de combien. Notre article sur la méthode du budget de trésorerie donne la démarche ; cet épisode la construit dans Excel, avec des formules qui se recopient et des paramètres qui se modifient.
Ce que vous saurez faire à la fin de l’épisode
- séparer hypothèses et calculs, avec des paramètres nommés ;
- convertir des ventes en encaissements décalés ;
- intégrer la TVA, une échéance d’emprunt et des charges fixes ;
- obtenir le solde cumulé et une alerte de seuil ;
- simuler un retard des clients avec les mêmes formules.
Les hypothèses
Dans un onglet Hypothèses, tout ce qui peut changer vit en cellules jaunes. Atlas Négoce démarre l’année avec 60 000 MAD en banque, fixe un seuil d’alerte de 50 000 MAD (environ six jours de décaissements, pour des sorties mensuelles proches de 245 000) et applique une TVA de 20 %.
Figure 1 : les hypothèses. Repère 1 : les délais d’encaissement de la base ; repère 2 : ceux du scénario de retard.
| Délai | Base | Retard clients |
|---|---|---|
| Encaissé le mois de la vente | 30 % | 10 % |
| Encaissé un mois après | 50 % | 40 % |
| Encaissé deux mois après | 20 % | 50 % |
Les achats sont payés à 40 % le mois même et à 60 % le mois suivant. Une cellule de contrôle vérifie que les trois pourcentages d’encaissement font bien 100 %, sinon le budget perdrait ou inventerait de l’argent.
Trois cellules reçoivent un nom : SoldeDepart, SeuilAlerte et TauxTVA (épisode 10). Les formules y gagnent en clarté.
Le budget, ligne par ligne
Chaque colonne est un mois, de janvier à juin. On a aussi saisi novembre et décembre : les ventes de ces deux mois sont encore en cours d’encaissement en janvier et février.
Figure 2 : le budget de base. Repère 1 : encaissements clients ; repère 2 : TVA à reverser ; repère 3 : solde de fin.
Les encaissements
=ARRONDI((D2*Hypothèses!$B$5+C2*Hypothèses!$B$6+B2*Hypothèses!$B$7)*(1+TauxTVA);0)Les ventes du mois (D2) sont encaissées à 30 % le mois même ; celles du mois précédent (C2) à 50 % ; celles d’il y a deux mois (B2) à 20 %. On multiplie par 1,20 : le client paie TTC. Pour janvier : (200 000 × 30 % + 210 000 × 50 % + 190 000 × 20 %) × 1,20 = 203 000 × 1,20 = 243 600. En recopiant vers la droite, D2, C2 et B2 glissent d’une colonne, et les $ figent la colonne des pourcentages.
Les paiements aux fournisseurs
=ARRONDI((D3*Hypothèses!$B$8+C3*Hypothèses!$B$9)*(1+TauxTVA);0)Même logique avec deux délais : janvier = (125 000 × 40 % + 130 000 × 60 %) × 1,20 = 153 600.
Salaires, loyer, emprunt, autres charges
Ces lignes sont des saisies : 45 000 de salaires et charges sociales, 12 000 de loyer, 6 000 d’autres décaissements, et l’échéance d’emprunt de 11 655,56 (celle de l’offre A de l’épisode 40, qui s’intègre ainsi au budget).
La TVA
=MAX(0;ARRONDI((C2-(C3*Hypothèses!$B$8+B3*Hypothèses!$B$9))*TauxTVA;0))La TVA payée en janvier porte sur décembre : TVA collectée sur les ventes de décembre (210 000), diminuée de la TVA récupérable sur les achats payés en décembre (130 000 × 40 % + 120 000 × 60 % = 124 000), soit (210 000 − 124 000) × 20 % = 17 200. Le MAX(0;…) ignore un éventuel crédit de TVA.
Simplification. Cette règle suppose que la TVA est exigible à la vente et déductible au paiement des achats, ce qui correspond à notre exemple de négoce de marchandises. Les règles d’exigibilité varient selon la nature de l’opération (voir l’article sur le fait générateur et l’exigibilité de la TVA) ; adaptez la ligne à votre activité.
Le solde et l’alerte
Total décaissements : =SOMME(D5:D10)
Flux net du mois : =D4-D11
Solde de début : =SoldeDepart (janvier) puis =D14, =E14…
Solde de fin : =D13+D12
Alerte : =SI(D14<SeuilAlerte;"Alerte";"OK")Le solde de début de chaque mois est le solde de fin du mois précédent : c’est le principe du budget de trésorerie, la chaîne des soldes.
Les résultats de base
| Mois | Encaissements | Décaissements | Flux net | Solde de fin |
|---|---|---|---|---|
| Janvier | 243 600 | 245 456 | −1 855,56 | 58 144,44 |
| Février | 249 600 | 243 856 | 5 744,44 | 63 888,88 |
| Mars | 270 000 | 262 056 | 7 944,44 | 71 833,32 |
| Avril | 310 800 | 290 856 | 19 944,44 | 91 777,76 |
| Mai | 340 800 | 313 456 | 27 344,44 | 119 122,20 |
| Juin | 333 600 | 292 256 | 41 344,44 | 160 466,64 |
Janvier est légèrement négatif (−1 855,56) : les achats et la TVA d’un mois de reprise partent avant les encaissements. Le solde reste au-dessus du seuil de 50 000. La croissance des ventes d’avril à juin fait monter la trésorerie, car les encaissements rattrapent les décaissements.
Le scénario de retard
Que se passe-t-il si les clients paient plus tard (10 % / 40 % / 50 %) ? L’onglet Budget retard a exactement les mêmes formules, mais lit la colonne C des hypothèses.
Figure 3 : le scénario de retard. Repère 1 : le solde de fin, sous le seuil en avril ; repère 2 : la ligne d’alerte.
| Mois | Solde de fin (base) | Solde de fin (retard) | Alerte (retard) |
|---|---|---|---|
| Janvier | 58 144,44 | 53 344,44 | OK |
| Février | 63 888,88 | 57 888,88 | OK |
| Mars | 71 833,32 | 51 433,32 | OK |
| Avril | 91 777,76 | 48 577,76 | Alerte |
| Mai | 119 122,20 | 62 722,20 | OK |
| Juin | 160 466,64 | 116 066,64 | OK |
Les ventes sont identiques, les charges aussi, mais le seul retard des clients abaisse la trésorerie de 44 400 MAD à fin juin (160 466,64 − 116 066,64) et la fait passer sous le seuil en avril, au moment où la TVA à reverser augmente avec les ventes. Ce montant de 44 400 est la somme encore due par les clients : une facture non encaissée est une avance de trésorerie accordée au client. Le moment et le montant du creux sont les deux informations que le dirigeant veut : en janvier, il sait déjà qu’il devra relancer ses clients, négocier un délai fournisseur ou prévoir une ligne de crédit pour avril.
Les erreurs classiques
- Budgéter le résultat au lieu des mouvements : on oublie les décalages, le remboursement du capital de l’emprunt (qui n’est pas une charge) ou la TVA.
- Oublier les mois d’avant : sans les ventes de novembre et décembre, janvier et février sous-estiment les encaissements.
- Écrire les pourcentages dans les formules : un délai de plus à tester demande de rouvrir toutes les formules.
- Ne pas rapprocher le réalisé du budget : la valeur du budget vient du suivi mensuel. Remplacez chaque mois les prévisions par le réalisé et prolongez l’horizon.
- Un seul scénario : le budget optimiste est celui qui ne dit jamais quand l’argent manquera.
À vous de jouer
Dans le classeur d’exercice :
- Onglet Budget : complétez les lignes 4, 5, 9 et 11 à 15. Retrouvez 243 600 (janvier) et 160 466,64 (solde de juin).
- Onglet Budget retard : même travail avec la colonne C. Quel mois déclenche l’alerte ?
- Dans Hypothèses, passez le seuil d’alerte à 60 000 : combien de mois sont en alerte en base, puis en retard ?
- Ajoutez une dépense exceptionnelle de 40 000 MAD en mars (achat de matériel) : que devient le point bas ?
Correction. (2) L’alerte se déclenche en avril (48 577,76). (3) En base, seul janvier (58 144,44) passe sous 60 000 : un mois d’alerte. Dans le scénario de retard, janvier (53 344,44), février (57 888,88), mars (51 433,32) et avril (48 577,76) sont sous le seuil, mai (62 722,20) ne l’est plus : quatre mois d’alerte. (4) La dépense de 40 000 en mars abaisse de 40 000 le solde de mars et ceux des mois suivants. En base, le solde de mars tombe à 31 833,32, nouveau point bas, sous le seuil de 50 000 ; avril (51 777,76) repasse juste au-dessus.
À retenir
- Le budget de trésorerie suit les mouvements de banque, pas le résultat.
- Les délais sont des pourcentages en paramètres ; une formule recopiée donne tous les mois.
- Prévoyez la TVA, l’emprunt (capital compris) et les charges fixes.
- Solde de début = solde de fin du mois précédent ; une alerte compare le solde au seuil.
- Comparez plusieurs scénarios et mettez le budget à jour chaque mois avec le réalisé.
Épisode 42 : le BFR et les ratios, avec fonds de roulement, trésorerie nette et délais clients-fournisseurs calculés depuis la balance.
Questions fréquentes
Pourquoi une entreprise rentable peut-elle manquer de trésorerie ?
Parce que le résultat comptable compte les ventes à leur facturation, alors que la banque ne bouge qu’à l’encaissement. Si les clients paient à 60 jours et les fournisseurs à 30, l’entreprise finance la différence : plus elle grandit, plus elle consomme de trésorerie. Le budget montre le moment précis où cela devient tendu.
Faut-il budgéter avec ou sans TVA ?
Avec : la banque encaisse les ventes toutes taxes comprises, paie les achats toutes taxes comprises et verse ensuite la TVA à l’État. Un budget hors taxes oublie un décaissement qui peut représenter plusieurs semaines de marge.
Pourquoi répartir les encaissements en pourcentages ?
Parce qu’en réalité les clients ne paient pas tous au même moment. Quelques pourcents encaissés le mois même, une moitié le mois suivant, le reste deux mois après : ces pourcentages se lisent dans l’historique des règlements et se modifient en une cellule pour simuler un retard.
À quelle fréquence faut-il mettre le budget à jour ?
Chaque mois, en remplaçant les prévisions du mois écoulé par le réalisé et en prolongeant l’horizon d’un mois (budget glissant). Un budget fait en janvier et jamais relu perd vite sa valeur.
Articles rédigés par l’équipe du cabinet à partir des textes officiels et de la pratique des missions. Chaque article indique sa date de publication et, le cas échéant, de dernière revue.